llGetAgentSize

vector llGetAgentSize(key AvatarID)

If the avatar is in the same region, returns the size of the bounding box of the requested avatar by id, otherwise returns ZERO_VECTOR.

If the agent is in the same region as the object, returns the size of the avatar.

Parameters

AvatarID (key)

Technical Details

Return Type: vector
Energy: 10

The returned vector is an estimate calculated from the avatar’s current shape including shoes:
- x is a constant 0.45 (DEFAULT_AGENT_DEPTH)
- y is a constant 0.60 (DEFAULT_AGENT_WIDTH)
- z is the approximate total height of all avatar’s bones, with an arbitrary amount added or subtracted based on the current shape’s “Hover” setting
- Reported height is constrained to the range 1.1 to 2.45 meters, and does not include animation or mesh bone offsets
Due to the shape Hover setting, and mesh and animation offsets, it is not possible to use this function to determine the rendered height of an avatar with any degree of confidence.
As of Second Life Server 13.11.19.284082, the return value is the avatar’s reported bounding box minus <0.1, 0.1, 0.2> when standing. Avatar bounding boxes have historically been redefined with major physics upgrades.
An avatar’s bounding box changes when an avatar sits, while llGetAgentSize is constant for as long as the shape does not change.
Returns ZERO_VECTOR if the avatar is not in the region or if it is not an avatar.

Examples

// A simple script that makes a box hover above the owner's head.
default
{
    state_entry()
    {
        key    owner = llGetOwner();
        vector pos   = llList2Vector(llGetObjectDetails(owner, [OBJECT_POS]), 0);
        vector agent = llGetAgentSize(owner);

    //  "pos" needs to be adjusted so it appears above the owner.
        pos.z += 0.5 + agent.z / 2;

    //  makes sure it found the owner, a zero vector evaluates as false
        if(agent)
            llSetPos(pos);
    }

    touch_start(integer num)
    {
        llResetScript();
    }
}

Notes

This function is a good way to quickly test:
- If an avatar is in the same region
- If a UUID known to be in the region is an avatar
To test either case:
```
if(llGetAgentSize(uuid)) {
    // uuid is an avatar in the region
} else {
    // uuid is not an avatar in the region
}
```
DEFAULT_AGENT_HEIGHT in the viewer’s indra_constants.h is 1.9. This will be the z value if an avatar’s shape has not loaded yet. It is possible but extremely rare to see a fully loaded avatar with this exact size:
```
vector agentSize = llGetAgentSize(uuid);
if (agentSize.z == 1.9) {
    // avatar is probably Ruthed
}
```

llGetAgentSize

Examples

Notes

See Also