Skip to content
Second Life Creation

llGetLinkName

string llGetLinkName(integer LinkNumber)

Returns the name of LinkNumber in a link set.

Returns the name of LinkNumber the link set.

Parameters
LinkNumber (integer)
Technical Details
  • Return Type: string
  • Energy: 10
  • If link is out of bounds, NULL_KEY is returned.
  • The prim name attribute is limited to 63 bytes, any string longer than that will be truncated. This truncation does not always happen when the attribute is set or read.
  • There is no corresponding llSetLinkName, use llSetLinkPrimitiveParamsFast(link, [PRIM_NAME, name]); instead.

Examples

Section titled “Examples”

Listen on channel 10 for a name and check if a prim with that name is part of this object:

integer check_for_prim(string name)
{
    integer i = llGetNumberOfPrims();
    for (; i >= 0; --i)
    {
        if (llGetLinkName(i) == name)
        {
            return TRUE;
        }
    }
    return FALSE;
}


default
{
    state_entry()
    {
        llListen(10, "", llGetOwner(), "");
    }
    listen(integer chan, string obj, key id, string msg)
    {
        if (check_for_prim(msg))
        {
            llOwnerSay("found a linked prim named \"" + msg + "\"");
        }
        else
        {
            llOwnerSay("this object does not have any linked prims named \"" + msg + "\"");
        }
    }
}

Helper Functions

Section titled “Helper Functions”

Get a link number by the prim name:

integer getLinkWithName(string name) {
    integer i = llGetLinkNumber() != 0;   // Start at zero (single prim) or 1 (two or more prims)
    integer x = llGetNumberOfPrims() + i; // [0, 1) or [1, llGetNumberOfPrims()]
    for (; i < x; ++i)
        if (llGetLinkName(i) == name)
            return i; // Found it! Exit loop early with result
    return -1; // No prim with that name, return -1.
}

See Also

Section titled “See Also”
Section titled “Related Articles”
  • Prim Attribute Overloading