Skip to content
Second Life Creation

llRequestSecureURL

key llRequestSecureURL()

Requests one HTTPS:// (SSL) URL for use by this object. The http_request event is triggered with results.

Returns a key that is the handle used for identifying the request in the http_request event.

Technical Details
  • Return Type: key
  • Energy: 10
  • HTTPS-in uses port 12043 (that port is in the URL returned by this method)
  • When a region is (re)started all HTTP server URLs are automatically released and invalidated
    • Use CHANGED_REGION_START to detect this so a new URL can be requested
  • Important: Never forget to release a URL after requesting it! URLs are region resources just like prims. Failing to release them can cause issues with the region owner and estate managers.

Examples

Section titled “Examples”

Basic Secure URL Request

Section titled “Basic Secure URL Request”

This example demonstrates how to request a secure URL, handle the response, and automatically re-request if the URL is dropped:

string secureUrl;
key urlRequestId;
key selfCheckRequestId;


request_secure_url()
{
    llReleaseURL(secureUrl);
    secureUrl = "";


    urlRequestId = llRequestSecureURL();
}


throw_exception(string inputString)
{
    key owner = llGetOwner();
    llInstantMessage(owner, inputString);


    // yeah, bad way to handle exceptions by restarting.
    // However this is just a demo script...


    llResetScript();
}


default
{
    on_rez(integer start_param)
    {
        llResetScript();
    }


    changed(integer change)
    {
        if (change & (CHANGED_OWNER | CHANGED_INVENTORY))
        {
            llReleaseURL(secureUrl);
            secureUrl = "";


            llResetScript();
        }


        if (change & (CHANGED_REGION | CHANGED_REGION_START | CHANGED_TELEPORT))
            request_secure_url();
    }


    state_entry()
    {
        request_secure_url();
    }


    http_request(key id, string method, string body)
    {
        integer responseStatus = 400;
        string responseBody = "Unsupported method";


        if (method == URL_REQUEST_DENIED)
            throw_exception("The following error occurred while attempting to get a free URL for this device:\n \n" + body);


        else if (method == URL_REQUEST_GRANTED)
        {
            secureUrl = body;
            key owner = llGetOwner();
            llLoadURL(owner, "Click to visit my URL!", secureUrl);


            // check every 5 mins for dropped URL
            llSetTimerEvent(300.0);
        }
        else if (method == "GET")
        {
            responseStatus = 200;
            responseBody = "Hello world!";
        }
        // else if (method == "POST") ...;
        // else if (method == "PUT") ...;
        // else if (method == "DELETE") { responseStatus = 403; responseBody = "forbidden"; }


        llHTTPResponse(id, responseStatus, responseBody);
    }


    http_response(key id, integer status, list metaData, string body)
    {
        if (id == selfCheckRequestId)
        {
            // If you're not usually doing this,
            // now is a good time to get used to doing it!
            selfCheckRequestId = NULL_KEY;


            if (status != 200)
                request_secure_url();
        }


        else if (id == NULL_KEY)
            throw_exception("Too many HTTP requests too fast!");
    }


    timer()
    {
        selfCheckRequestId = llHTTPRequest(secureUrl,
                                [HTTP_METHOD, "GET",
                                    HTTP_VERBOSE_THROTTLE, FALSE,
                                    HTTP_BODY_MAXLENGTH, 16384],
                                "");
    }
}

See Also

Section titled “See Also”